#include <IRremote.h>

/**
 * Digital pin that will detect the interrupt via H11AA1.
 */
const int PIN_INTERRUPT = 2;

/**
 * Digital pin that leads to MOC 3052 triac driver.
 */
const int PIN_TRIAC = 7;

/**
 * Pin for IR receiving.
 */
const int PIN_IR = 35;

IRrecv irrecv(PIN_IR);     
decode_results results;

int dimValue;

void setup() {

    pinMode(PIN_INTERRUPT, INPUT);
    pinMode(PIN_TRIAC, OUTPUT);
    pinMode(LED_BUILTIN, OUTPUT);

    digitalWrite(PIN_TRIAC, LOW);
    digitalWrite(LED_BUILTIN, LOW);

    dimValue = 50;

    irrecv.enableIRIn();

    Serial.begin(38400);

    interrupts();
    attachInterrupt(digitalPinToInterrupt(PIN_INTERRUPT), zeroCrossing, FALLING);
}

void loop() {

    if (irrecv.decode(&results)) {// Returns 0 if no data ready, 1 if data ready.
      if (results.value != 0xFFFFFFFF){

          Serial.println(results.value, HEX);

          if (results.value == 0x1FEA05F && dimValue < 100){ // For decreasing brightness of LED
              dimValue += 5;
          } else if (results.value == 0x1FE609F && dimValue > 50){ // For increasing brightness of LED
              dimValue -= 5;
          }
      }  
      irrecv.resume(); // Restart the ISR state machine and Receive the next value
    
    }
}

/**
 * AC frequency = 50 Hz.
 * So, time period one full wave = 20 ms.
 * Therefore, time period of half the wave (time period from one zero crossing to another) = 10 ms = 10,000 μs.
 * 
 * Number of steps (taken arbitraily) = 100.
 * => Each step corresponds to 10,000 μs/100 = 100 μs.
 * ∴ Time for dimming = (100 * dimValue) μs.
 */
void zeroCrossing(){
    int delayMicros = 100 * dimValue;
    delayMicroseconds(delayMicros);
    digitalWrite(PIN_TRIAC, HIGH);
    delayMicroseconds(10);
    digitalWrite(PIN_TRIAC, LOW);
}